mirror of
https://github.com/amnezia-vpn/amnezia-client.git
synced 2026-05-08 14:33:23 +00:00
78f504e35c
* feat: iap for apple now use storekit2 * fix: fixed error 101 on connection event * feat: enhance StoreKit2Helper to handle entitlements and improve restore service from App Store functionality * chore: add isInAppPurchase and isTestPurchase in primary config * refactor: use end_date from primary config for renew ui * fix: hide renew button for free * fix: hide renew button for appstore purchases * feat: add new premium info page * feat: add new free info page * chore: minor fixes * refactor: move plan and benefits into separate models * fix: fixed expired status when configs without an end date * feat: add trial api support * chore: add api message parsing for 422 error * feat: move privacy policy and term of use to gateway * feat: add iap support for new premium info page * chore: minor fixes * chore: minor fix * chore: minor fixes * feat: additional parsing for storekit subscription plans * chore: minor codestyle fixes * chore: simplify benefits * chore: hide extend buttons on external premium * feat: add trial error processing * fix: remove wrong check from tiral handler * chore: cleanup --------- Co-authored-by: spectrum <yyy@amnezia.org>
95 lines
2.6 KiB
QML
95 lines
2.6 KiB
QML
import QtQuick
|
|
import QtQuick.Layouts
|
|
|
|
import Style 1.0
|
|
|
|
import "../Controls2/TextTypes"
|
|
|
|
Rectangle {
|
|
id: root
|
|
|
|
property bool selected: false
|
|
property string billingPeriod: ""
|
|
property string priceLabel: ""
|
|
property string subtitle: ""
|
|
property bool showRecommendedBadge: false
|
|
property string recommendedText: "Recommended"
|
|
|
|
signal selectRequested
|
|
|
|
implicitHeight: cardLayout.implicitHeight + 28
|
|
radius: 16
|
|
color: AmneziaStyle.color.transparent
|
|
border.width: selected ? 2 : 1
|
|
border.color: selected ? AmneziaStyle.color.goldenApricot : AmneziaStyle.color.charcoalGray
|
|
|
|
ColumnLayout {
|
|
id: cardLayout
|
|
|
|
anchors.left: parent.left
|
|
anchors.right: parent.right
|
|
anchors.verticalCenter: parent.verticalCenter
|
|
anchors.leftMargin: 16
|
|
anchors.rightMargin: 16
|
|
|
|
spacing: 8
|
|
|
|
RowLayout {
|
|
Layout.fillWidth: true
|
|
|
|
LabelTextType {
|
|
Layout.fillWidth: true
|
|
text: root.billingPeriod
|
|
color: root.selected ? AmneziaStyle.color.goldenApricot : AmneziaStyle.color.paleGray
|
|
font.pixelSize: 17
|
|
font.weight: Font.DemiBold
|
|
wrapMode: Text.Wrap
|
|
}
|
|
|
|
LabelTextType {
|
|
text: root.priceLabel
|
|
color: root.selected ? AmneziaStyle.color.goldenApricot : AmneziaStyle.color.paleGray
|
|
font.pixelSize: 17
|
|
font.weight: Font.DemiBold
|
|
}
|
|
}
|
|
|
|
RowLayout {
|
|
Layout.fillWidth: true
|
|
visible: root.subtitle.length > 0 || root.showRecommendedBadge
|
|
|
|
LabelTextType {
|
|
Layout.fillWidth: true
|
|
text: root.subtitle
|
|
color: AmneziaStyle.color.mutedGray
|
|
font.pixelSize: 13
|
|
wrapMode: Text.Wrap
|
|
}
|
|
|
|
Rectangle {
|
|
visible: root.showRecommendedBadge
|
|
Layout.alignment: Qt.AlignVCenter
|
|
radius: 10
|
|
color: AmneziaStyle.color.softViolet
|
|
implicitHeight: recLabel.implicitHeight + 8
|
|
implicitWidth: recLabel.implicitWidth + 16
|
|
|
|
LabelTextType {
|
|
id: recLabel
|
|
|
|
anchors.centerIn: parent
|
|
text: root.recommendedText
|
|
color: AmneziaStyle.color.midnightBlack
|
|
font.pixelSize: 11
|
|
font.weight: Font.Medium
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
MouseArea {
|
|
anchors.fill: parent
|
|
onClicked: root.selectRequested()
|
|
}
|
|
}
|